class_name CameraGimbal extends Node3D

@export var rotation_speed = (PI / 180) * 120
@export var shift_lock = false
@export var default_zoom = 8

var mouse_locked = false
var mouse_velocity = Vector2.ZERO
var locked_mouse_position = Vector2.ZERO

var current_zoom = default_zoom
var zoom_min = 4
var zoom_max = 80
var zoom_speed = 20

func reset():
	basis = Basis()
	$InnerGimbal.basis = Basis()
	current_zoom = default_zoom

func rotate_camera_y(y, delta):
	rotate_object_local(Vector3.UP, y * rotation_speed * delta)
func rotate_camera_x(x, delta):
	$InnerGimbal.rotate_object_local(
		Vector3.RIGHT, x * rotation_speed * delta)
	$InnerGimbal.rotation.x = clamp($InnerGimbal.rotation.x, -0.8, 0.7)

func _input(event):
	if event is InputEventMouseMotion:
		mouse_velocity = event.relative
	elif event.is_action_pressed("zoom_out"):
		current_zoom += 1
	elif event.is_action_pressed("zoom_in"):
		current_zoom -= 1

	current_zoom = clamp(current_zoom, zoom_min, zoom_max)

func _process(delta):
	var y = 0
	var x = 0

	if Input.is_action_just_pressed("shift_lock"):
		shift_lock = not shift_lock
	if Input.is_mouse_button_pressed(MOUSE_BUTTON_RIGHT) or shift_lock == true:
		if mouse_locked == false:
			mouse_locked = true
			locked_mouse_position = get_viewport().get_mouse_position()
		Input.set_mouse_mode(Input.MOUSE_MODE_CAPTURED)

		if mouse_velocity.x > 5 or mouse_velocity.x < -5:
			y -= clamp(mouse_velocity.x / 12.5, -10, 10)
		if mouse_velocity.y > 5 or mouse_velocity.y < -5:
			x -= clamp(mouse_velocity.y / 12.5, -10, 10)
	else:
		Input.set_mouse_mode(Input.MOUSE_MODE_VISIBLE)
		mouse_velocity = Vector2.ZERO
		mouse_locked = false

	rotate_camera_y(y, delta)
	rotate_camera_x(x, delta)

	if Input.is_action_pressed("cam_reset"):
		reset()

	var pos = Vector3($InnerGimbal/Camera3D.position)
	pos.y = lerp(pos.y, float(current_zoom), zoom_speed * delta)
	pos.z = lerp(pos.z, float(current_zoom), zoom_speed * delta)

	$InnerGimbal/Camera3D.position = pos
